nixos-config/linux/quasar/zfs.nix

{
  config,
  lib,
  ...
}: {
  boot = {
    loader.grub.zfsSupport = true;
    zfs = {
      extraPools = ["zarchive"];
      requestEncryptionCredentials = ["zactive/main"];
    };
  };

  services.zfs = {
    autoScrub.enable = true;
    trim.enable = true;
  };

  services.zrepl = {
    enable = true;
    settings = {
      global = {
        logging = [
          {
            type = "syslog";
            level = "info";
            format = "human";
          }
        ];
      };
      jobs = let
        archiveBaseName = "archive";
        backupBaseName = "backup";
        pushConfig = name: grid: {
          type = "push";
          name = "push-${name}";
          connect = {
            type = "local";
            listener_name = "${name}-listener";
            client_identity = config.networking.hostName;
          };
          filesystems."zactive/main/home" = true;
          send.encrypted = true;
          snapshotting.type = "manual";
          pruning = {
            keep_sender = [
              {
                type = "regex";
                regex = "^zrepl-.*";
              }
            ];
            keep_receiver = [
              {
                type = "grid";
                regex = "^zrepl-.*";
                grid = lib.concatStringsSep " | " grid;
              }
            ];
          };
          replication.protection = {
            initial = "guarantee_resumability";
            incremental = "guarantee_incremental";
          };
        };
        sinkConfig = name: dataset: {
          type = "sink";
          name = "sink-${name}";
          serve = {
            type = "local";
            listener_name = "${name}-listener";
          };
          root_fs = dataset;
          recv.placeholder.encryption = "off";
        };
      in [
        {
          type = "snap";
          name = "snapshot";
          filesystems."zactive/main/home" = true;
          snapshotting = {
            type = "periodic";
            prefix = "zrepl-";
            interval = "1h";
          };
          pruning = {
            keep = [
              {
                type = "grid";
                regex = "^zrepl-.*";
                grid = lib.concatStringsSep " | " ["1x1h(keep=all)" "24x1h" "7x1d" "4x1w"];
              }
            ];
          };
        }
        (pushConfig archiveBaseName ["1x1h(keep=all)" "30x1d" "52x1w"])
        (pushConfig backupBaseName ["8x13w"])
        (sinkConfig archiveBaseName "zarchive/snapshot")
        (sinkConfig backupBaseName "zbackup/snapshot")
      ];
    };
  };
}