nixos-config/flake.nix

{
  description = "Entrypoint of all nix configurations";

  inputs = {
    disko.url = "github:nix-community/disko";
    hardware.url = "github:nixos/nixos-hardware";
    home-manager.url = "github:nix-community/home-manager";
    jovian.url = "github:Jovian-Experiments/Jovian-NixOS";
    mailserver.url = "gitlab:simple-nixos-mailserver/nixos-mailserver";
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    nix-custom.url = "/home/macronova/Desktop/nix-custom";
    sops-nix.url = "github:Mic92/sops-nix";
  };

  outputs = inputs@{ self, nixpkgs, nix-custom, ... }:
    let
      linuxCfgDir = ./linux;
      templateDir = ./template;
    in
    {
      nixosConfigurations = builtins.mapAttrs
        (instance: _:
          nixpkgs.lib.nixosSystem ({
            modules = [
              # Import config from folder
              (linuxCfgDir + "/${instance}")
              # Setup Nix
              ({ pkgs, ... }: {
                networking.hostName = instance;
                nix = {
                  gc = {
                    automatic = true;
                    options = "--delete-older-than 30d";
                  };
                  settings = {
                    auto-optimise-store = true;
                    experimental-features = [ "nix-command" "flakes" ];
                    trusted-substituters = [ "https://mirrors.tuna.tsinghua.edu.cn/nix-channels/store" ];
                  };
                };
                nixpkgs = {
                  config.allowUnfree = true;
                  overlays = [ nix-custom.overlays.default ];
                };
              })
            ];
            specialArgs = { inherit inputs; };
          }))
        (builtins.readDir linuxCfgDir);
      templates = builtins.mapAttrs
        (template: _: {
          path = templateDir + "/${template}";
          description = "Template flake setup: ${template}";
        })
        (builtins.readDir templateDir);
    };

}