nixos-config/linux/protostar/gui.nix

{
  config,
  inputs,
  pkgs,
  ...
}: let
  userName = config.constants.userName;
  jovianPkgs = pkgs.extend inputs.jovian.overlays.default;
in {
  home-manager.users.${userName} = {config, ...}: {
    home = {
      file.".local/share/fonts".source = config.lib.file.mkOutOfStoreSymlink "/run/current-system/sw/share/X11/fonts";
      packages = with jovianPkgs; [
        feishin
        lutris
        maliit-keyboard
        (retroarch.override {
          cores = with libretro; [
            pcsx2
            ppsspp
          ];
        })
        ryujinx
        winetricks
        wineWowPackages.stagingFull
      ];
    };
  };
  jovian = {
    devices.steamdeck = {
      enable = true;
      autoUpdate = true;
    };
    steam = {
      enable = true;
      autoStart = true;
      desktopSession = "plasma";
      user = userName;
    };
  };

  services = {
    desktopManager.plasma6.enable = true;
    pipewire = {
      enable = true;
      alsa = {
        enable = true;
        support32Bit = true;
      };
      pulse.enable = true;
    };
  };

  hardware = {
    bluetooth.enable = true;
    graphics.enable = true;
  };
}